MTAN.bas

The following BASIC program was developed using the freeware Chipmunk Basic {http://www.nicholson.com/rhn/basic/) and estimates mortality and survival from a size distribution using growth parameters of the Tanaka function, f, d, and a. Other input values are size at recruitment, S0, and an initial guess of the value of M; 0.1 or 0.01 are good guesses. If the program does not converge or converges on a nonsense answer such as negative M, select a different starting value.

When there are two or more input values on a line such as lines 70 and 120, separate values with commas. For example, in line 70 the prompt is you should enter size, 1.5, and time, 0

Size and time at recruitment: 1.5,0

10 dim lt(10000),t(10000)

20 print "Estimating M with Tanaka parameters"

30 print " June 1992 update August 2018 T. A. Ebert"

40 print : input "Do you want to continue? (y/n) ";s$

50 if s$ = "N" or s$ = "n" then goto 470

60 input "Mean size: ";ms

70 input "Size and time at recruitment: ";s0,t0

80 input "Do you want to use the same parameters as the last run? (y/n)";s$

90 if s$ = "Y" or s$ = "y" then goto 160

100 print

110 print

120 input "Enter f, d, and a: ";f,d,a

150 input "Enter an initial estimate for M:";z

160 g = -log(1.000000E-08)

180 e = exp(sqr(f)\*(s0-d))

190 c = a/e-e/4/f

200 for j = 1 to 10000

210 fz = 0.

220 dz = 0

230 fs = 0

240 ds = 0

250 for i = 0 to (g/z+0.5)

260 t = i+t0

270 lt(i) = 1/sqr(f)\*log(2\*abs(f\*(t-c)+sqr(f\*f\*(t-c)^2+f\*a)))+d

290 fz = fz+exp(-z\*i)

300 dz = dz-i\*exp(-z\*i)

310 fs = fs+exp(-z\*i)\*lt(i)

320 ds = ds-i\*exp(-z\*i)\*lt(i)

330 next i

340 dz = (fz\*ds-fs\*dz)/(fz\*fz)

360 fs = fs/fz-ms

380 cr = fs/dz

390 z = z-cr

410 if abs(cr) <= 1.000000E-06 then goto 430

420 next j

430 print "Final M = ";z

435 print "Survival P = ";exp(-z)

440 print

450 print

460 goto 40

470 end

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

MGAMMA.bas

The following program is structured the same as MTAN.bas but uses parameters of the Gamma model of Ellers & Johnson 2009, Ebert 2013a) with parameters and called K, L, and A on line 120.

M

10 dim lt(10000),t(10000)

20 print "Estimating Z with Gamma parameters"

30 print March 2012, update August 2018 T. A. Ebert"

40 print : input "Do you want to continue? (y/n) ";s$

50 if s$ = "N" or s$ = "n" then goto 470

60 input "Mean size: ";ms

70 input "Size and time at recruitment: ";s0,t0

80 input "Do you want to use the same parameters as the last run? (y/n)";s$

90 if s$ = "Y" or s$ = "y" then goto 160

100 print

110 print

120 input "Enter K, L and A: ";K,L,A

150 input "Enter an initial estimate for Z:";z

160 g = -log(1.000000E-08)

163 lt(0)=s0

165 for k=1 to 500

168 lt(k)=lt(k-1)+ K\*EXP(-lt(k-1)/L)\*lt(k-1)^(A-1)

170 next k

200 for j = 1 to 10000

210 fz = 0

220 dz = 0

230 fs = 0

240 ds = 0

250 for i = 0 to (g/z+0.5)

260 t = i+t0

290 fz = fz+exp(-z\*i)

300 dz = dz-i\*exp(-z\*i)

310 fs = fs+exp(-z\*i)\*lt(i)

320 ds = ds-i\*exp(-z\*i)\*lt(i)

330 next i

340 dz = (fz\*ds-fs\*dz)/(fz\*fz)

360 fs = fs/fz-ms

380 cr = fs/dz

390 z = z-cr

410 if abs(cr) <= 1.000000E-06 then goto 430

420 next j

430 print "Final M = ";z

435 print "Survival P = ";exp(-z)

440 print

450 print

460 goto 40

470 end